home *** CD-ROM | disk | FTP | other *** search
/ QRZ! Ham Radio 8 / QRZ Ham Radio Callsign Database - Volume 8.iso / mac / files / t_sys5 / unixcpio.gz / unixnet.cpio / pcgen.asm < prev    next >
Assembly Source File  |  1994-07-11  |  6KB  |  344 lines
  1.     include    pmacros.h
  2.  
  3. dseg
  4. jtable    dw    l0,l1,l2,l3,l4,l5,l6,l7,l8,l9,l10,l11,l12,l13,l14,l15    
  5. pubvar    sssave,<dw ?>
  6. pubvar    spsave,<dw ?>
  7.     db    512 dup(?)
  8. pubvar    intstk,<label byte>
  9. pubvar    mtasker,<db ?>
  10. extvar    isat,<byte>
  11. dsegend
  12.  
  13. ; common routine for interrupt return
  14.     pubproc    doret
  15.     pop    es
  16.     pop    di
  17.     pop    si
  18.     pop    bp
  19.     pop    dx
  20.     pop    cx
  21.     pop    bx
  22.     cmp    isat@,1
  23.     jnz    notat        ; Only one 8259, so skip this stuff
  24.     mov    al,0bh        ; read in-service register from
  25.     out    0a0h,al        ; secondary 8259
  26.     nop            ; settling delay
  27.     nop
  28.     nop
  29.     in    al,0a0h        ; get it
  30.     or    al,al        ; Any bits set?
  31.     jz    notat        ; nope, not a secondary interrupt
  32.     mov    al,20h        ; Get EOI instruction
  33.     out    0a0h,al        ; Secondary 8259 (PC/AT only)
  34. notat:    mov    al,20h        ; 8259 end-of-interrupt command
  35.     out    20h,al        ; Primary 8259
  36.     mov    ss,sssave@
  37.     mov    sp,spsave@    ; restore original stack context
  38.     pop    ds
  39.     pop    ax
  40.     iret
  41.     pend    doret
  42.  
  43. if TURBO
  44. else
  45. ; setvect - set interrupt vector
  46. ; called from C as follows
  47. ; setvect(vec,vecval)
  48. ; char vec;        /* Interrupt number */
  49. ; void (*vecval)();    /* offset (and segment in large code model) */
  50.  
  51.     procdef    setvect,<<vec,byte>,<ipval,fptr>>
  52.     mov    ah,25h
  53.     mov    al,vec
  54.     push    ds        ; save
  55. ifdef    LARGECODE
  56.     lds    dx,ipval
  57. else
  58.     mov    dx,ipval
  59.     push    cs
  60.     pop    ds
  61. endif
  62.     int    21h
  63.     pop    ds        ; restore
  64.     pret
  65.     pend    setvect
  66.  
  67. ; getvect - return current interrupt vector
  68. ; called from C as
  69. ; long        /* Returns CS in high word, IP in low word */
  70. ; getvect(vecnum)
  71. ; char vecnum;    /* Interrupt number */
  72.  
  73.     procdef    getvect,<<vecnum,byte>>
  74.     mov    ah,35h
  75.     mov    al,vecnum
  76.     push    es    ; save, since DOS uses it for a return value
  77.     int    21h
  78.     mov    dx,es    ; CS value into DX (C high word)
  79.     mov    ax,bx    ; IP value into AX (C low word)
  80.     pop    es    ; restore es
  81.     pret
  82.     pend    getvect
  83. endif
  84.  
  85. ; kbraw - raw, nonblocking read from console
  86. ; If character is ready, return it; if not, return -1
  87.  
  88.     procdef    kbraw
  89.     mov    ah,06h    ; Direct Console I/O
  90.     mov    dl,0ffh    ; Read from keyboard
  91.     int    21h    ; Call DOS
  92.     jz    nochar    ; zero flag set -> no character ready
  93.     mov    ah,0    ; valid char is 0-255
  94.     pret
  95. nochar:
  96.     mov    ax,-1    ; no char, return -1
  97.     pret
  98.     pend    kbraw
  99.  
  100. ; disable - disable interrupts and return previous state: 0 = disabled,
  101. ;           1 = enabled
  102.  
  103.     procdef    disable
  104.     pushf            ; save state on stack
  105.     cli            ; interrupts off
  106.     pop    ax        ; original flags -> ax
  107.     and    ax,200h        ; 1<<9 is IF bit
  108.     jnz    ion        ; nonzero -> interrupts were on
  109.     pret
  110. ion:    mov    ax,1
  111.     pret
  112.     pend    disable
  113.  
  114. ; restore - restore interrupt state: 0 = off, nonzero = on
  115.  
  116.     procdef    restore,<<istate,byte>>
  117.     test    istate,0ffh
  118.     jz    ioff
  119.     sti
  120. ioff:    pret
  121.     pend    restore
  122.  
  123. ; Halt until an interrupt occurs, then return
  124.     procdef eihalt
  125.     sti    ; make sure interrupts are enabled
  126.     hlt
  127.     pret
  128.     pend    eihalt
  129.  
  130. ; multitasker types
  131. NONE        equ    0
  132. DOUBLEDOS    equ    1
  133. DESQVIEW    equ    2
  134.  
  135. ; Relinquish processor so other task can run
  136.     procdef    giveup
  137.     cmp    mtasker@, DOUBLEDOS
  138.     jnz    givedesqview
  139.     mov    al,2        ; 110 ms
  140.     mov    ah,0eeh
  141.     int    21h
  142.  
  143. givedesqview:
  144.     cmp    mtasker@, DESQVIEW
  145.     jnz    notask
  146.     mov    ax, 1000h
  147.     int    15h
  148. notask:
  149.     pret
  150.     pend    giveup
  151.  
  152. ; check for a multitasker running
  153.     procdef chktasker
  154.     mov    mtasker@, NONE
  155.     ; do the doubledos test
  156.     mov    ah, 0e4h
  157.     int    21h
  158.     cmp    al, 1
  159.     jz    isdos
  160.     cmp    al, 2
  161.     jnz    test_desq
  162. isdos:    mov    mtasker@, DOUBLEDOS
  163.     pret
  164.  
  165.     ; test for desqview
  166. test_desq:
  167.     mov    ax, 2b01h
  168.     mov    cx, 4445h
  169.     mov    dx, 5351h
  170.     int    21h
  171.     cmp    al, 0ffh
  172.     jnz    isdesq
  173.     pret
  174. isdesq:    mov    mtasker@, DESQVIEW
  175.     pret
  176.     pend    chktasker
  177.  
  178. ; getds - Read DS for debugging purposes
  179.     procdef    getds
  180.     getds
  181.     pret
  182.     pend    getds
  183.  
  184. ; Internet checksum subroutine
  185. ; Compute 1's-complement sum of data buffer
  186. ; Uses an unwound loop inspired by "Duff's Device" for performance
  187. ;
  188. ; Called from C as
  189. ; unsigned short
  190. ; lcsum(buf,cnt)
  191. ; unsigned short *buf;
  192. ; unsigned short cnt;
  193.     procdef    lcsum,<<buf,ptr>,<cnt,word>>
  194.     pushds            ; save if using large model
  195.     push    si
  196.     ldptr    si,buf,ds    ; ds:si = buf
  197.     mov    cx,cnt        ; cx = cnt
  198.     cld            ; autoincrement si
  199.  
  200.     mov    ax,cx
  201.     shr    cx,1        ; cx /= 16, number of loop iterations
  202.     shr    cx,1
  203.     shr    cx,1
  204.     shr    cx,1
  205.  
  206.     inc    cx        ; make fencepost adjustment for 1st pass
  207.     and    ax,15        ; ax = number of words modulo 16
  208.     shl    ax,1        ; *=2 for word table index
  209.     lea    bx,jtable    ; bx -> branch table
  210.     add    bx,ax        ; index into jump table
  211.     clc            ; initialize carry = 0
  212.     mov    dx,0        ; clear accumulated sum
  213.     jmp    word ptr[bx]    ; jump into loop
  214.  
  215. ; Here the real work gets done. The numeric labels on the lodsw instructions
  216. ; are the targets for the indirect jump we just made.
  217. ;
  218. ; Each label corresponds to a possible remainder of (count / 16), while
  219. ; the number of times around the loop is determined by the quotient.
  220. ;
  221. ; The loop iteration count in cx has been incremented by one to adjust for
  222. ; the first pass.
  223. ; 
  224. deloop:    lodsw
  225.     adc    dx,ax
  226. l15:    lodsw
  227.     adc    dx,ax
  228. l14:    lodsw
  229.     adc    dx,ax
  230. l13:    lodsw
  231.     adc    dx,ax
  232. l12:    lodsw
  233.     adc    dx,ax
  234. l11:    lodsw
  235.     adc    dx,ax
  236. l10:    lodsw
  237.     adc    dx,ax
  238. l9:    lodsw
  239.     adc    dx,ax
  240. l8:    lodsw
  241.     adc    dx,ax
  242. l7:    lodsw
  243.     adc    dx,ax
  244. l6:    lodsw
  245.     adc    dx,ax
  246. l5:    lodsw
  247.     adc    dx,ax
  248. l4:    lodsw
  249.     adc    dx,ax
  250. l3:    lodsw
  251.     adc    dx,ax
  252. l2:    lodsw
  253.     adc    dx,ax
  254. l1:    lodsw
  255.     adc    dx,ax
  256. l0:    loop    deloop        ; :-)
  257.  
  258.     adc    dx,0        ; get last carries
  259.     adc    dx,0
  260.     mov    ax,dx        ; result into ax
  261.     xchg    al,ah        ; byte swap result (8088 is little-endian)
  262.     pop    si
  263.     popds            ; all done
  264.     pret
  265.     pend    lcsum
  266. ;
  267. ; dos service routine used by JK1NNT installed by N3EUA
  268. ;
  269.     procdef    jkintdos,<<reg_a,word>,<reg_b,word>,<reg_d,word>>
  270.     mov    ax,reg_a
  271.     mov    bx,reg_b
  272.     mov    dx,reg_d
  273.     int    21h
  274.     pret
  275.     pend    jkintdos
  276. ;
  277. ; NEC PC-9801 speed setting routine by JK1NNT installed by N3EUA
  278. ;
  279.     procdef    set_speed,<<s_code,word>>
  280.     push    ds
  281.     mov    ax,40h
  282.     mov    ds,ax
  283.     mov    dx,s_code
  284.     mov    ds:[269h],dl
  285.     mov    dh,4ch
  286.     mov    ds:[268h],dh
  287.     pop    ds
  288.     mov    cl,0ah
  289.     int    0dch
  290.     pret
  291.     pend    set_speed
  292.  
  293. ;
  294. ; This routine is a generic int 21h handler, is used only by disk free
  295. ; routine.  Added by K3MC  3 Dec 87
  296. ;
  297. ;
  298. ; General-purpose int 21h caller, currently used only to return AX, BX, CX, DX
  299. ; for computing amount of free disk space, and amount of total disk space.
  300. ;
  301. ; declared as: void isfree();
  302. ;
  303. ; Called from C as:
  304. ;
  305. ; isfree(&ax,&bx,&cx,&dx)
  306. ; unsigned short ax,bx,cx,dx;
  307. ;
  308.     procdef    isfree,<<c_ax,ptr>,<c_bx,ptr>,<c_cx,ptr>,<c_dx,ptr>>
  309.     push    ax
  310.     push    bx
  311.     push    cx
  312.     push    dx
  313.     push    bp
  314.     push    si
  315.     push    di
  316.     ldptr    di,c_ax,ds
  317.     mov    ax,[di]
  318.     ldptr    di,c_bx,ds
  319.     mov    bx,[di]
  320.     ldptr    di,c_cx,ds
  321.     mov    cx,[di]
  322.     ldptr    di,c_dx,ds
  323.     mov    dx,[di]
  324.     int     21h
  325.     ldptr    di,c_ax,ds
  326.     mov    [di],ax
  327.     ldptr    di,c_bx,ds
  328.     mov    [di],bx
  329.     ldptr    di,c_cx,ds
  330.     mov    [di],cx
  331.     ldptr    di,c_dx,ds
  332.     mov    [di],dx
  333.     pop    di
  334.     pop    si
  335.     pop    bp
  336.     pop    dx
  337.     pop    cx
  338.     pop    bx
  339.     pop    ax
  340.     pret
  341.     pend    isfree
  342.  
  343.     end
  344.